Directorty Opus 5 - Magellan 2/Opus 5 - Magellan 2.iso/Extras/Install_3.3/Install english

Text File | 1997-06-05 | 5KB | 143 lines

; $VER: Install.install eng 3.3 (05.06.97)

(set @default-dest "DOpus5:")
(set @language "english")

(complete 0)

(set exec-version (/ (getversion) 65536))
(if (< exec-version 38)
 (abort "This program needs at least OS 2.1.\n")
)

(message (cat "\nVersion Installation program\n"
              "for Directory Opus Magellan:\n\n"
              "written by Frédéric Steinfels\n"
              "[e-mail]\n\n"
              "This program is EMailWare.\n"
              "Send me an email if you are using it!"
         )
)

(complete 6)

(set #updatefile "Update file")
(set #noupdatefile "Do not update file")

(procedure Updatefile

(set #dest (askdir (prompt (cat "Where is or where do you want to have " #file " installed?"))
             (help "Select the drawer where you want to install this file. Please use the given/default path.")
                  (default (cat #dest))
         )
)

(set vernum1 (getversion (tackon #dest #file)) )
(set ver1 (/ vernum1 65536))
(set rev1 (- vernum1 (* ver1 65536) ) )


(set vernum2 (getversion (tackon #source #file)) )
(set ver2 (/ vernum2 65536))
(set rev2 (- vernum2 (* ver2 65536) ) )


(set #text  (cat "'" #file "'\n~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~~\n"
                  "Version Currently Installed   : " ver1 "." rev1 "\n\n"
                  "Version in this Archive/Update: " ver2 "." rev2 "\n\n"
                  "Do you wish to install Version " ver2 "." rev2 " of "
                  "'" #file "' from the Archive/Update?"
             )
)


(set pick (askchoice (choices #updatefile #noupdatefile) (prompt #text)    (help #text) (default pick)))

(if (= pick 0) (copyfiles (source (tackon #source #file )) (dest #dest))))

;end Procedure

(set upver
    (askchoice
        (prompt "The command C:Version 40.1 (09.02.1993) contains a severe bug that can crash the whole system if the last four bytes of a file contain a $ sign. The probability is 1.6% for each file. The original version command will be renamed to 'version.old'.\nThis patch was made by Urs Eprecht.\n")
        (help "I suggest you to get the version command from the Workbench 3.1 distribution as the patch is only working with this version. Unfortunately I don't know wheter this problem occurs also under other OS versions. Please select 'Remove this bug'.\nAs this bug fix requires some additional bytes, the text 'This disk requires Kickstart 2.04 or greater' will be shortened to 'OS 2.04 required'.")
        (choices
            "Remove this bug"
            "Don't touch c:Version"
        )
    )
)

(if (= upver 0)
    (
        (rename "c:Version" "c:Version.old")
        (if
            (run ("c/spatch -oC:Version -pVersion/version.pch C:Version.old"))
            (
                (message "Unfortunately I haven't been able to patch C:Version. Either this file has already been modified or it is of a different version (not Workbench 3.1).")
                (rename "c:Version.old" "c:Version")
            )
            (
                (message "C:Version successfully updated!")
            )
        )
    )
)

(set #file "Install_Execute.dopus5")          (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 12)

(set #file "Install_GetID.dopus5")            (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 18)

(set #file "Install_Main.dopus5")             (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 25)

(set #file "Install_Preferences.dopus5")      (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 31)

(set #file "Install_Request.dopus5")          (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 37)

(set #file "Install_Scan.dopus5")             (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 43)

(set #file "Install_Startup.dopus5")          (set #source "ARexx")   (set #dest "DOpus5:ARexx")   (Updatefile)
(complete 50)

(set #file "Install.dopus5_eng.guide")        (set #source "")        (set #dest "DOpus5:Help")    (Updatefile)
(set #guide-dest #dest)
(complete 56)

(set #file "rexxdossupport.library")          (set #source "libs")    (set #dest "Libs:")          (Updatefile)
(complete 62)

(set #file "rexxtricks.library")              (set #source "libs")    (set #dest "Libs:")          (Updatefile)
(complete 68)

(set #file "Install_Locale.prefs")            (set #source "System")  (set #dest "DOpus5:System")  (Updatefile)
(complete 75)

(set #file "Install_Main.prefs")              (set #source "System")  (set #dest "DOpus5:System")  (Updatefile)
(complete 81)

(set #file "Install_Preferences_english")             (set #source "Buttons") (set #dest "DOpus5:Buttons") (Updatefile)
(set #button-dest #dest)
(complete 87)

(complete 93)


(rexx "ARexx/InstallerHelp.rexx" (tackon #button-dest "Install_Preferences_english") "::" (tackon #guide-dest "Install.dopus5_eng.guide"))

(complete 100)

(message (cat "\nInstallation complete\n\n"
              "Please read the guide (" (tackon #guide-dest "Install.dopus5_eng.guide") ") carefully.\n"
              "Don't forget that you can easily open it by clicking with your right mouse button on 'show Settings' in the upper left corner of the toolbar.\n"
              "Sorry for this not so intuitive toolbar but a real graphical user interface would have wasted a lot of ram.\n\n"
              "\n"
              "Have fun and don't forget to send me an email!\n"
         (all))
)
(exit (quiet))